encoding  iso8859-1
text de "area u:blocks_hdens" "Felsbl��cke, Versturz"
text en "area u:blocks_hdens" "blocks, breakdown"
text fr "area u:blocks_hdens" "blocs, effondrement"

layout area_blocks_hdens
  code metapost
    % area blocks high density
    def a_u_blocks_hdens (expr p) =
      % blocks distance/density
      if unknown blocks_distance:
        blocks_distance:=0.6;
      fi
      % shift between blocks
      if unknown blocks_shift:
        blocks_shift:=1.5;
      fi
      % blocks size
      if unknown blocks_size:
        blocks_size:=0.5;
      fi
      T:=identity;
      pickup PenC;
      path q, qq; q = bbox p;
      picture tmp_pic; 
      uu := max(u, (xpart urcorner q - xpart llcorner q)/100, (ypart urcorner q - ypart llcorner q)/100);
      tmp_pic := image(
        for i = xpart llcorner q step (blocks_distance*uu) until xpart urcorner q:
          for j = ypart llcorner q step (blocks_distance*uu) until ypart urcorner q:
            qq := punked (((-(blocks_size*uu),-(blocks_size*uu))--((blocks_size*uu),-(blocks_size*uu))--((blocks_size*uu),(blocks_size*uu))--(-(blocks_size*uu),(blocks_size*uu))--cycle)
                 randomized (uu/2))
                 rotated uniformdeviate(360) 
                 shifted ((i,j) randomized (blocks_shift*uu));
            if xpart (p intersectiontimes qq) < 0:
              thclean qq;
              thdraw qq;
            fi;
          endfor;  
        endfor;
      );
      clip tmp_pic to p;
      draw tmp_pic;
    enddef;
    initsymbol("a_u_blocks_hdens");
  endcode
endlayout